Windows Update

[Excavator]

Running XP64.
I open a 32bit browser window, click Tools/Windows Update and it goes to http://update.microsoft.com/windowsupdate/v6/default.aspx?ln=en-us but that doesn't load. I'm redirected to http://v4.windowsupdate.microsoft.com/en/thanks.asp which shows me a Scan for Updates link that does not work.

How am I getting redirected to the older v4 of update???

 

[Excavator]

Any ideas on this yet?
It looks like I'm going to have to do a format/re-install to fix this.

 

[Phoenix86]

Link.

Check and see if any of these resolve your issues.

 

[MorfiusX]

Save the following as a .vbs and run it. This is a script I created to fix numerous Windows Update errors.

' ==========================================================================
' Name: Windows Update Fix
' Filename: UpdateFix.vbs
' Author: (MorfiusX)
' Created: 11/09/2005
' Notes: Use this script to fix issues involved with Windows Update.
' Changes:
' ==========================================================================
Set objShell = WScript.CreateObject("WScript.Shell")
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
Set LogFile = objFSO.OpenTextFile("C:\UpdateFix.log", 2, True)
Set arrArgs = WScript.Arguments
Ver = "v1.0"

Function Menu()
	Prompt = "1. Run all fixes." &Chr(13)&Chr(10)& _
		"2. Register Windows Update files." &Chr(13)&Chr(10)& _
		"3. Set secuirty context." &Chr(13)&Chr(10)& _
		"4. Force machine scan." &Chr(13)&Chr(10)& _
		"5. Delete update cache." &Chr(13)&Chr(10)& _
		"6. Exit."
	Menu = InputBox(Prompt,"Windows Update Fix " & Ver,"1")
End Function

Sub StopServices()
	objShell.Run "%windir%\system32\net.exe stop bits",0,True
	If Err.Number <> 0 Then
		LogFile.WriteLine(Date & " " & Time & " - Stoping Background Intellegent Transfer Service - " & Err.Number & ": " & Err.Description & ". " & Err.Source & ".")
		Err.Clear
	Else
		LogFile.WriteLine(Date & " " & Time & " - Stoping Background Intellegent Transfer Service: OK")
	End If
	objShell.Run "%windir%\system32\net.exe stop wuauserv",0,True
	If Err.Number <> 0 Then
		LogFile.WriteLine(Date & " " & Time & " - Stoping Automatic Updates Service - " & Err.Number & ": " & Err.Description & ". " & Err.Source & ".")
		Err.Clear
	Else
		LogFile.WriteLine(Date & " " & Time & " - Stoping Automatic Updates Service: OK")
	End If
End Sub

Sub StartServices()
	objShell.Run "%windir%\system32\net.exe start bits",0,True
	If Err.Number <> 0 Then
		LogFile.WriteLine(Date & " " & Time & " - Stoping Background Intellegent Transfer Service - " & Err.Number & ": " & Err.Description & ". " & Err.Source & ".")
		Err.Clear
	Else
		LogFile.WriteLine(Date & " " & Time & " - Stoping Background Intellegent Transfer Service: OK")
	End If
	objShell.Run "%windir%\system32\net.exe start wuauserv",0,True
	If Err.Number <> 0 Then
		LogFile.WriteLine(Date & " " & Time & " - Stoping Automatic Updates Service - " & Err.Number & ": " & Err.Description & ". " & Err.Source & ".")
		Err.Clear
	Else
		LogFile.WriteLine(Date & " " & Time & " - Stoping Automatic Updates Service: OK")
	End If
End Sub

Sub RegFiles()
	objShell.Exec "%windir%\system32\regsvr32.exe /s %windir%\system32\atl.dll"
	objShell.Exec "%windir%\system32\regsvr32.exe /s %windir%\system32\jscript.dll"
	objShell.Exec "%windir%\system32\regsvr32.exe /s %windir%\system32\msxml3.dll"
	objShell.Exec "%windir%\system32\regsvr32.exe /s %windir%\system32\softpub.dll"
	objShell.Exec "%windir%\system32\regsvr32.exe /s %windir%\system32\wuapi.dll"
	objShell.Exec "%windir%\system32\regsvr32.exe /s %windir%\system32\wuaueng.dll"
	objShell.Exec "%windir%\system32\regsvr32.exe /s %windir%\system32\wuaueng1.dll"
	objShell.Exec "%windir%\system32\regsvr32.exe /s %windir%\system32\wucltui.dll"
	objShell.Exec "%windir%\system32\regsvr32.exe /s %windir%\system32\wups.dll"
	objShell.Exec "%windir%\system32\regsvr32.exe /s %windir%\system32\wuweb.dll"
End Sub

Sub SetContext()
	Set objWshScriptExec = objShell.Exec("%windir%\system32\sc.exe sdset wuauserv D:(A;;CCLCSWRPWPDTLOCRRC;;;SY)(A;;CCDCLCSWRPWPDTLOCRSDRCWDWO;;;BA)(A;;CCLCSWLOCRRC;;;AU)(A;;CCLCSWRPWPDTLOCRRC;;;PU)")
	Set objStdOut = objWshScriptExec.StdOut
	While Not objStdOut.AtEndOfStream
		strLine = objStdOut.ReadLine
		LogFile.WriteLine(Date & " " & Time & " - " & strLine)
	Wend
End Sub

Sub ForceScan()
	On Error Resume Next
	objShell.RegDelete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update\LastWaitTimeout"
	objShell.RegDelete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update\DetectionStartTime"
	objShell.RegDelete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update\NextDetectionTime"
	On Error GoTo 0
End Sub

Sub DelCache()
	objFSO.DeleteFolder "C:\WINDOWS\SoftwareDistribution"
	If Err.Number <> 0 Then
		LogFile.WriteLine(Date & " " & Time & " - Deleting Update Cache - " & Err.Number & ": " & Err.Description & ". " & Err.Source & ".")
		Err.Clear
	Else
		LogFile.WriteLine(Date & " " & Time & " - Deleting Update Cache: OK")
	End If
End Sub

Sub Launch()
	Input = Menu()
	If Input = "1" Then
		Call StopServices()
		Call RegFiles()
		Call SetContext()
		Call ForceScan()
		Call DelCache()
		Call StartServices()
		Call Done()
	Elseif Input = "2" Then
		Call StopServices()
		Call RegFiles()
		Call StartServices()
		Call Done()
	Elseif Input = "3" Then
		Call StopServices()
		Call SetContext()
		Call StartServices()
		Call Done()
	Elseif Input = "4" Then
		Call StopServices()
		Call ForceScan()
		Call StartServices()
		Call Done()
	Elseif Input = "5" Then
		Call StopServices()
		Call DelCache()
		Call StartServices()
		Call Done()
	Elseif Input = "6" Then
	Else
		WScript.Echo "Not a valid selection. Please choose a valid option."
		Launch()
	End If
End Sub

Sub Done()
	WScript.Echo "Done! A log has been written to C:\UpdateFix.log." &Chr(13)&Chr(10)& _
		"Please check it for errors."
End Sub

On Error Resume Next
Args = Null
Args = arrArgs(0)
If Args = "/?" Then
	On Error GoTo 0
	WScript.Echo "Help Section..."
Elseif Args = "/s" Then
	On Error GoTo 0
	Call StopServices()
	Call RegFiles()
	Call SetContext()
	Call ForceScan()
	Call DelCache()
	Call StartServices()
	WScript.Echo "Done"
Else
	On Error GoTo 0
	Call Launch()
End If

 

[Excavator]

Wow, both of those were new. I followed everything on the page you linked Phoenix86 and then I ran MorfiusX .vbs file (that's pretty cool).

Same thing though.
When I click on WindowsUpdate I can see the v6 url in the address bar but it's quickly replaced with the v4 url.